mirror of https://github.com/bjeanes/dotfiles.git
185 lines
8.4 KiB
Bash
185 lines
8.4 KiB
Bash
|
#!/usr/bin/env zsh
|
||
|
|
# -------------------------------------------------------------------------------------------------
|
||
|
|
# Copyright (c) 2010-2011 zsh-syntax-highlighting contributors
|
||
|
|
# All rights reserved.
|
||
|
|
#
|
||
|
|
# Redistribution and use in source and binary forms, with or without modification, are permitted
|
||
|
|
# provided that the following conditions are met:
|
||
|
|
#
|
||
|
|
# * Redistributions of source code must retain the above copyright notice, this list of conditions
|
||
|
|
# and the following disclaimer.
|
||
|
|
# * Redistributions in binary form must reproduce the above copyright notice, this list of
|
||
|
|
# conditions and the following disclaimer in the documentation and/or other materials provided
|
||
|
|
# with the distribution.
|
||
|
|
# * Neither the name of the zsh-syntax-highlighting contributors nor the names of its contributors
|
||
|
|
# may be used to endorse or promote products derived from this software without specific prior
|
||
|
|
# written permission.
|
||
|
|
#
|
||
|
|
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
|
||
|
|
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
|
||
|
|
# FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
|
||
|
|
# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
|
||
|
|
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
||
|
|
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
|
||
|
|
# IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
|
||
|
|
# OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
||
|
|
# -------------------------------------------------------------------------------------------------
|
||
|
|
# -*- mode: zsh; sh-indentation: 2; indent-tabs-mode: nil; sh-basic-offset: 2; -*-
|
||
|
|
# vim: ft=zsh sw=2 ts=2 et
|
||
|
|
# -------------------------------------------------------------------------------------------------
|
||
|
|
|
||
|
|
|
||
|
|
# Define default styles.
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[default]:=none}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[unknown-token]:=fg=red,bold}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[reserved-word]:=fg=yellow}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[alias]:=fg=green}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[builtin]:=fg=green}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[function]:=fg=green}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[command]:=fg=green}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[precommand]:=fg=green,underline}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[commandseparator]:=none}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[hashed-command]:=fg=green}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[path]:=underline}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[globbing]:=fg=blue}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[history-expansion]:=fg=blue}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[single-hyphen-option]:=none}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[double-hyphen-option]:=none}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[back-quoted-argument]:=none}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[single-quoted-argument]:=fg=yellow}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[double-quoted-argument]:=fg=yellow}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[dollar-double-quoted-argument]:=fg=cyan}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[back-double-quoted-argument]:=fg=cyan}
|
||
|
|
: ${ZSH_HIGHLIGHT_STYLES[assign]:=none}
|
||
|
|
|
||
|
|
# Whether the highlighter should be called or not.
|
||
|
|
_zsh_highlight_main_highlighter_predicate()
|
||
|
|
{
|
||
|
|
_zsh_highlight_buffer_modified
|
||
|
|
}
|
||
|
|
|
||
|
|
# Main syntax highlighting function.
|
||
|
|
_zsh_highlight_main_highlighter()
|
||
|
|
{
|
||
|
|
setopt localoptions extendedglob bareglobqual
|
||
|
|
local start_pos=0 end_pos highlight_glob=true new_expression=true arg style
|
||
|
|
typeset -a ZSH_HIGHLIGHT_TOKENS_COMMANDSEPARATOR
|
||
|
|
typeset -a ZSH_HIGHLIGHT_TOKENS_PRECOMMANDS
|
||
|
|
typeset -a ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS
|
||
|
|
region_highlight=()
|
||
|
|
|
||
|
|
ZSH_HIGHLIGHT_TOKENS_COMMANDSEPARATOR=(
|
||
|
|
'|' '||' ';' '&' '&&'
|
||
|
|
)
|
||
|
|
ZSH_HIGHLIGHT_TOKENS_PRECOMMANDS=(
|
||
|
|
'builtin' 'command' 'exec' 'nocorrect' 'noglob'
|
||
|
|
)
|
||
|
|
# Tokens that are always immediately followed by a command.
|
||
|
|
ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS=(
|
||
|
|
$ZSH_HIGHLIGHT_TOKENS_COMMANDSEPARATOR $ZSH_HIGHLIGHT_TOKENS_PRECOMMANDS
|
||
|
|
)
|
||
|
|
|
||
|
|
for arg in ${(z)BUFFER}; do
|
||
|
|
local substr_color=0
|
||
|
|
[[ $start_pos -eq 0 && $arg = 'noglob' ]] && highlight_glob=false
|
||
|
|
((start_pos+=${#BUFFER[$start_pos+1,-1]}-${#${BUFFER[$start_pos+1,-1]##[[:space:]]#}}))
|
||
|
|
((end_pos=$start_pos+${#arg}))
|
||
|
|
if $new_expression; then
|
||
|
|
new_expression=false
|
||
|
|
if [[ -n ${(M)ZSH_HIGHLIGHT_TOKENS_PRECOMMANDS:#"$arg"} ]]; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[precommand]
|
||
|
|
else
|
||
|
|
res=$(LC_ALL=C builtin type -w $arg 2>/dev/null)
|
||
|
|
case $res in
|
||
|
|
*': reserved') style=$ZSH_HIGHLIGHT_STYLES[reserved-word];;
|
||
|
|
*': alias') style=$ZSH_HIGHLIGHT_STYLES[alias]
|
||
|
|
local aliased_command="${"$(alias $arg)"#*=}"
|
||
|
|
[[ -n ${(M)ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS:#"$aliased_command"} && -z ${(M)ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS:#"$arg"} ]] && ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS+=($arg)
|
||
|
|
;;
|
||
|
|
*': builtin') style=$ZSH_HIGHLIGHT_STYLES[builtin];;
|
||
|
|
*': function') style=$ZSH_HIGHLIGHT_STYLES[function];;
|
||
|
|
*': command') style=$ZSH_HIGHLIGHT_STYLES[command];;
|
||
|
|
*': hashed') style=$ZSH_HIGHLIGHT_STYLES[hashed-command];;
|
||
|
|
*) if _zsh_highlight_main_highlighter_check_assign; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[assign]
|
||
|
|
new_expression=true
|
||
|
|
elif _zsh_highlight_main_highlighter_check_path; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[path]
|
||
|
|
elif [[ $arg[0,1] = $histchars[0,1] ]]; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[history-expansion]
|
||
|
|
else
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[unknown-token]
|
||
|
|
fi
|
||
|
|
;;
|
||
|
|
esac
|
||
|
|
fi
|
||
|
|
else
|
||
|
|
case $arg in
|
||
|
|
'--'*) style=$ZSH_HIGHLIGHT_STYLES[double-hyphen-option];;
|
||
|
|
'-'*) style=$ZSH_HIGHLIGHT_STYLES[single-hyphen-option];;
|
||
|
|
"'"*"'") style=$ZSH_HIGHLIGHT_STYLES[single-quoted-argument];;
|
||
|
|
'"'*'"') style=$ZSH_HIGHLIGHT_STYLES[double-quoted-argument]
|
||
|
|
region_highlight+=("$start_pos $end_pos $style")
|
||
|
|
_zsh_highlight_main_highlighter_highlight_string
|
||
|
|
substr_color=1
|
||
|
|
;;
|
||
|
|
'`'*'`') style=$ZSH_HIGHLIGHT_STYLES[back-quoted-argument];;
|
||
|
|
*"*"*) $highlight_glob && style=$ZSH_HIGHLIGHT_STYLES[globbing] || style=$ZSH_HIGHLIGHT_STYLES[default];;
|
||
|
|
*) if _zsh_highlight_main_highlighter_check_path; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[path]
|
||
|
|
elif [[ $arg[0,1] = $histchars[0,1] ]]; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[history-expansion]
|
||
|
|
elif [[ -n ${(M)ZSH_HIGHLIGHT_TOKENS_COMMANDSEPARATOR:#"$arg"} ]]; then
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[commandseparator]
|
||
|
|
else
|
||
|
|
style=$ZSH_HIGHLIGHT_STYLES[default]
|
||
|
|
fi
|
||
|
|
;;
|
||
|
|
esac
|
||
|
|
fi
|
||
|
|
[[ $substr_color = 0 ]] && region_highlight+=("$start_pos $end_pos $style")
|
||
|
|
[[ -n ${(M)ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS:#"$arg"} ]] && new_expression=true
|
||
|
|
start_pos=$end_pos
|
||
|
|
done
|
||
|
|
}
|
||
|
|
|
||
|
|
# Check if the argument is variable assignment
|
||
|
|
_zsh_highlight_main_highlighter_check_assign()
|
||
|
|
{
|
||
|
|
setopt localoptions extended_glob
|
||
|
|
[[ ${(Q)arg} == [[:alpha:]_]([[:alnum:]_])#=* ]]
|
||
|
|
}
|
||
|
|
|
||
|
|
# Check if the argument is a path.
|
||
|
|
_zsh_highlight_main_highlighter_check_path()
|
||
|
|
{
|
||
|
|
setopt localoptions nonomatch
|
||
|
|
local expanded_path; : ${expanded_path:=${(Q)~arg}}
|
||
|
|
[[ -z $expanded_path ]] && return 1
|
||
|
|
[[ -e $expanded_path ]] && return 0
|
||
|
|
[[ ! -e ${expanded_path:h} ]] && return 1
|
||
|
|
[[ ${BUFFER[1]} != "-" && ${#BUFFER} == $end_pos && -n $(print ${expanded_path}*(N)) ]] && return 0
|
||
|
|
return 1
|
||
|
|
}
|
||
|
|
|
||
|
|
# Highlight special chars inside double-quoted strings
|
||
|
|
_zsh_highlight_main_highlighter_highlight_string()
|
||
|
|
{
|
||
|
|
setopt localoptions noksharrays
|
||
|
|
local i j k style
|
||
|
|
# Starting quote is at 1, so start parsing at offset 2 in the string.
|
||
|
|
for (( i = 2 ; i < end_pos - start_pos ; i += 1 )) ; do
|
||
|
|
(( j = i + start_pos - 1 ))
|
||
|
|
(( k = j + 1 ))
|
||
|
|
case "$arg[$i]" in
|
||
|
|
'$') style=$ZSH_HIGHLIGHT_STYLES[dollar-double-quoted-argument];;
|
||
|
|
"\\") style=$ZSH_HIGHLIGHT_STYLES[back-double-quoted-argument]
|
||
|
|
(( k += 1 )) # Color following char too.
|
||
|
|
(( i += 1 )) # Skip parsing the escaped char.
|
||
|
|
;;
|
||
|
|
*) continue;;
|
||
|
|
esac
|
||
|
|
region_highlight+=("$j $k $style")
|
||
|
|
done
|
||
|
|
}
|